# PyMOL 0.95+ script for yeast Phe-tRNA (PDB entry 1EVV)
# ------------------------------------------------------
# Luca Jovine, MSSM NY (luca.jovine@mssm.edu) 
# Version 1.4.1 - 040503
#
#
delete *
mclear
#
# load tRNA coordinates:
cd ~/Desktop/nuccyl_1evv
load 1EVV_rnaview.pdb, 1evv
#
# define RNA:
create trna, (1evv and not (resn SPM or resn MG or resn HOH))
# define spermine:
create spermine, 1evv and resn SPM
# define tigthly bound magnesium ions (1-4):
# - MG 1 (near nt 8, 9, 11, 12, 13):
create mg_01s, 1evv and resn MG and resi 901 
# - MG 2 (near nt 20, 21):
create mg_02s, 1evv and resn MG and resi 902
# - MG 3 (near nt 18, 19, 20, 59, 60):
create mg_03s, 1evv and resn MG and resi 903
# - MG 4 (near nt 24, 25, 26, 27, 41, 42, 43):
create mg_04s, 1evv and resn MG and resi 904
# define weakly bound magnesium ions (5-10):
create mg_05w, 1evv and resn MG and resi 905
create mg_06w, 1evv and resn MG and resi 906
create mg_07w, 1evv and resn MG and resi 907
create mg_08w, 1evv and resn MG and resi 908
create mg_09w, 1evv and resn MG and resi 909
create mg_10w, 1evv and resn MG and resi 910
# define water molecules:
create water, 1evv and resn HOH
#
# load coordinates of pseudo atoms defining nucleotide cylinders:
load nuccyl3.pdb, nuccyl3
#
hide lines
hide nonbonded
#
# diplay RNA ribbon:
set cartoon_oval_length = 0.7
set cartoon_oval_width = 1.2
set cartoon_oval_quality = 25
set cartoon_loop_radius = 1.0
set cartoon_loop_quality = 25
set cartoon_refine_tips = 25
set cartoon_power = 2
set cartoon_power_b = 0.5
set cartoon_sampling = 20
set cartoon_throw = 1
# either use "cartoon oval" or "cartoon loop", the latter being somewhat smoother:
#cartoon oval
cartoon loop
show cartoon, trna
#
# display spermine:
util.cbay (spermine)
set stick_radius = 0.4, spermine
show stick, spermine
#
# display magnesium ions:
set sphere_scale = 0.6, mg_01s or mg_02s or mg_03s or mg_04s or mg_05w or mg_06w or mg_07w or mg_08w or mg_09w or mg_10w
show spheres, mg_01s or mg_02s or mg_03s or mg_04s or mg_05w or mg_06w or mg_07w or mg_08w or mg_09w or mg_10w
# - color tigthly bound magnesium ions:
color forest, mg_01s or mg_02s or mg_03s or mg_04s
# - color weakly bound magnesium ions:
color lime, mg_05w or mg_06w or mg_07w or mg_08w or mg_09w or mg_10w
#
# display water molecules:
set sphere_scale = 0.25, water
show spheres, water
#
# generate nucleotide cylinders:
@nuccyl3.pml
delete pk1
delete pk2
delete pkfrag1
delete pkfrag2
delete pkchain
set stick_radius = 0.4, resn X
show sticks, resn X
#
# color acceptor stem:
color magenta, (trna) and (resi 1:7 or resi 66:72)
color magenta, G1 or C2 or G3 or G4 or A5 or U6 or U7
color magenta, A66 or A67 or U68 or U69 or C70 or G71 or C72
#
# color nucleotides 8,9:
color orange, (trna) and (resi 8:9)
color orange, U8 or A9
#
# color D stem:
color slate, (trna) and (resi 10:13 or resi 22:25)
color slate, 2MG10 or C11 or U12 or C13
color slate, G22 or A23 or G24 or C25
#
# color D loop:
color slate, (trna) and (resi 14:21)
color slate, A14 or G15 or H2U16 or H2U17 or G18 or G19 or G20 or A21
#
# color nucleotide 26:
color red, (trna) and (resi 26)
color red, M2G26
#
# color anticodon stem:
color red, (trna) and (resi 27:31 or resi 39:43)
color red, C27 or C28 or A29 or G30 or A31
color red, PSU39 or 5MC40 or U41 or G42 or G43
#
# color anticodon loop:
color red, (trna) and (resi 32:38)
color red, OMC32 or U33 or OMG34 or A35 or A36 or YG37 or A38
#
# color variable loop:
color yellow, (trna) and (resi 44:48)
color yellow, A44 or G45 or 7MG46 or U47 or C48
#
# color T stem:
color marine, (trna) and (resi 49:53 or resi 61:65)
color marine, 5MC49 or U50 or G51 or U52 or G53
color marine, C61 or A62 or C63 or A64 or G65
#
# color T loop:
color marine, (trna) and (resi 54:60)
color marine, 5MU54 or PSU55 or C56 or G57 or 1MA58 or U59 or C60
#
# color ACCA 3' end:
color grey, (trna) and (resi 73:76)
color grey, A73 or C74 or C75 or A76
#
# fix the 5' end:
set sphere_scale = 0.55, resi 1 and name p
color magenta, resi 1 and name p
show sphere, resi 1 and name p
#
# fix the 3' end:
set sphere_scale = 0.55, resi 76 and name p
color grey, resi 76 and name p
show sphere, resi 76 and name p
#
# orient model:
viewport 640,480
zoom complete = 1
set_view (\
    -0.590555847,    0.099722713,   -0.800796449,\
    -0.731215358,    0.353664339,    0.583283365,\
     0.341386586,    0.930029273,   -0.135943294,\
     0.000464784,   -0.000572219, -212.857833862,\
    40.233577728,    1.744799972,   23.892095566,\
   157.049545288,  285.007476807,    0.000000000 )
#
# set up parameters for ray tracing:
set spec_power = 200
set spec_reflect = 1.5
set depth_cue = 1
set ray_trace_fog = 1
set antialias = 1
set max_threads = 2
#
# save session:
save phe_trna.pse